Pseint: Una universidad tiene N seccionales y cada seccional tiene NE estudiantes. De cada estudiante se conoce: código, nombre, estatura y edad
Elaborar un algoritmo que permita calcular y mostrar:
-El nombre del estudiante con la menor edad (el estudiante mas joven) de toda la universidad
-El nombre del estudiante con la menor edad (el estudiante mas joven) por seccional
Respuestas
Nota:
Algunas funciones podrian variar en funcion del perfi de Pseint que estes utilizando, por ejemplo, necesitar poner ; al final de cada linea o reemplazar los = por <-
Posdata:
Te agradeceria si me das la coronita Uwu
Código:
Algoritmo Universidad
//Estas son todas las variables que utilizaremos
Definir secciones, estudiantes, contador, otroContador, edad, codigo Como Entero
Definir nombre como Cadena
Definir estatura Como Real
//Estas variables almacenaran solo los alumnos menores
Definir nombreMenor,nombreMenorSeccion Como Cadena
Definir edadMenor, codigoMenor,edadMenorSeccion, codigoMenorSeccion Como Entero
Definir estaturaMenor, estaturaMenorSeccion Como real
//Ponemos un dato bastante grande para que el
//primer dato que se ingrese automaticamente sea el menor
edadMenor = 100
//Primero digitamos la cantidad de secciones
Escribir "Digite la cantidad de secciones"
Leer secciones
//Esto determina el tamaño del arreglo estudiantes
Dimension estudiantes[secciones]
//Determinamos los alumnos menores por secciones
Dimension nombreMenorSeccion[secciones]
Dimension edadMenorSeccion[secciones]
Dimension codigoMenorSeccion[secciones]
Dimension estaturaMenorSeccion[secciones]
//Asignamos cuantos estudiantes hay por secciones
Para contador = 1 Hasta secciones Con Paso 1 Hacer
Escribir "Digite cuantos alumnos hay en la seccion ",contador
Leer estudiantes[contador]
Fin Para
//Aqui recorremos cada seccion
Para contador = 1 Hasta secciones Con Paso 1 Hacer
//Antes de entrar con los alumoos le asignamos al menor un dato bastante
//grande para que el primer dato que se ingrese automaticamente sea el menor
edadMenorSeccion[contador] = 100
//Aqui recorremos cada alumno de seccion
Para otroContador = 1 Hasta estudiantes[contador] Con Paso 1 Hacer
Escribir "Digite el nombre del estudiante ",otroContador," de la seccion ",contador
Leer nombre
Escribir "Digite la edad del estudiante ",otroContador," de la seccion ",contador
Leer edad
Escribir "Digite el codigo del estudiante ",otroContador," de la seccion ",contador
Leer codigo
Escribir "Digite la estatura del estudiante ",otroContador," de la seccion ",contador
Leer estatura
//Esto es solo para dejar un espacio entre alumnos
Escribir " "
//Evaluamos que sea el menor de la seccion
Si edad < edadMenorSeccion[contador] Entonces
//Evaluamos que se el menor de todos
Si edad < edadMenor Entonces
//Le asignamos los valores al menor de todos
//y al menor de la seccion
edadMenor = edad
nombreMenor = nombre
codigoMenor = codigo
estaturaMenor = estatura
edadMenorSeccion[contador] = edad
nombreMenorSeccion[contador] = nombre
codigoMenorSeccion[contador] = codigo
estaturaMenorSeccion[contador] = estatura
SiNo
//Le asignamos los valores solo al menor de la seccion
edadMenorSeccion[contador] = edad
nombreMenorSeccion[contador] = nombre
codigoMenorSeccion[contador] = codigo
estaturaMenorSeccion[contador] = estatura
Fin Si
Fin Si
Fin Para
Fin Para
Escribir "La el estudiante con la menor edad es: ",nombreMenor," que tiene ",edadMenor," años, mide ",estaturaMenor," y su codigo es ",codigoMenor
Para contador = 1 Hasta secciones Con Paso 1 Hacer
Escribir "El alumno menor de la seccion ",contador," es ",nombreMenorSeccion[contador]
Escribir "Edad: ",edadMenorSeccion[contador]
Escribir "Código del alumno: ",codigoMenorSeccion[contador]
Escribir "Estatura: ",estaturaMenorSeccion[contador]
//Esto es para dejar espacio
Escribir " "
Fin Para
FinAlgoritmo