Question

1. Cree un arreglo de 10 posiciones
2. Cargue el arreglo con números enteros mayores de 0 y menores de 500, si los valores ingresados no cumplen con esta condición, indique por consola (salida), el número no es aceptado.
3. Calcule el promedio de los números ingresados
4. Indique cual es el valor mayor de los números ingresados
5. Muestre los valores ingresados, el promedio y el número mayor
Debe emplear ciclos (para, mientras y/o repetir)

Answer 1

Ya que no especifica lenguaje de programación el algoritmo sería:

Algoritmo arregloNnumeros

Dimension arreglo[10]

i <- 1

suma <- 0

numMayor <- -20000

Repetir

 Escribir "Ingrese numero:" Sin Saltar

 Leer num

 Si num>0 y num<500 Entonces

  arreglo[i]=num

  i<-i+1

  suma<-suma+num

  Si num>numMayor Entonces

   numMayor <- num

  Fin Si

 SiNo

  Escribir "El numero no es aceptado"

 Fin Si

Mientras Que i<=10

Escribir "Los numeros ingresados fueron:" Sin Saltar

Para Cada n de arreglo Hacer

 Escribir n, ", " Sin Saltar

Fin Para

Escribir " "

Escribir "Promedio:", suma/10

Escribir "Mayor:", numMayor

FinAlgoritmo

Hemos utilizado estructuras repetitivas: repetir y para.

En el primero caso nos permite ingresar los números al arreglo mientras validamos si estan o no dentro del rango, en caso de que esté fuera del rango, el contador o indice i no se incrementa y por lo tanto, el programa seguirá pidiendo e ingrese un nuevo valor para la misma ubicación

Al mismo tiempo también vamos acumulando la suma, que se utiliza luego para hallar el promedio y también vamos buscando el mayor.

Al final para imprimir los valores del arreglo usamos la estructura para