Question

Problema 3.
En un almacén de cadena, se desea implementar un programa para categorizar a las personas que ingresan, para ello se solicita que informen a que grupo pertenecen: ama de casa, empleado, propietario de negocio, jubilado, desempleado.
Al finalizar el día se deben presentar los resultados de cada categoría.

Answer 1

El algoritmo que resuelve el problema del conteo de las personas que ingresan al almacén durante el día de acuerdo a las categorías dadas es:

Algoritmo clasificacion_personas

Dimension categorias[5]

categorias[1]=0

categorias[2]=0

categorias[3]=0

categorias[4]=0

categorias[5]=0

Repetir

 Escribir "Nueva persona? s/n "

 Leer resp

 Si resp="s" Entonces

  Escribir "Categorias"

  Escribir "__________"

  Escribir "1. Ama de casa"

  Escribir "2. Empleado"

  Escribir "3. Propietario de negocio"

  Escribir "4. Jubilado"

  Escribir "5  Desempleado"

  Escribir "Seleccione una opcion: " Sin Saltar

  Leer op

  Segun op Hacer

   1:

    categorias[1]=categorias[1]+1

   2:

    categorias[2]=categorias[2]+1

   3:

    categorias[3]=categorias[3]+1

   4:

    categorias[4]=categorias[4]+1

   5:

    categorias[5]=categorias[5]+1

   

   De Otro Modo:

    Escribir "Opcion no valida"

  Fin Segun

 Fin Si

Hasta Que resp = "n"

Escribir "Los Resultados del dia:"

Escribir "Amas de casa: ", categorias[1]

Escribir "Empleados: ", categorias[2]

Escribir "Propietarios de negocio: ", categorias[3]

Escribir "Jubilados: ", categorias[4]

Escribir "Desempleados: ", categorias[5]

FinAlgoritmo

Hemos considerado que el proceso de registro y conteo se repita mientras siga ingresando personas con la opción "s"

En ese caso, seleccionará un categoría, lo que hará que el correspondiente contador en el array "categorías" se incremente en uno.

Finalmente, se muestran los resultados para cada categoría.